# Default command: lists all available just commands
default:
    just --list

# Rebuild the local NixOS system using a flake configuration
rebuild:
    nixos-rebuild switch --flake .#btc-pay-server

# Build the NixOS system configuration without switching
build:
    nix build .#nixosConfigurations.btc-pay-server.config.system.build.toplevel

# Deploy (rebuild) the NixOS system on the remote host
# Usage: just deploy root@10.1.1.163
deploy host:
    nixos-rebuild switch --fast --flake .#btc-pay-server --target-host {{host}} --build-host {{host}} --use-remote-sudo

# Check the status of bitcoind and btcpayserver services on the remote host
# Usage: just status root@10.1.1.163
status host:
    ssh {{host}} "systemctl status bitcoind btcpayserver"

# Encrypt the secrets.yaml file in place using sops
encrypt-secrets:
    sops -e -i secrets.yaml

# Open the secrets.yaml file for editing with sops
edit-secrets:
    sops secrets.yaml

# Open a developer shell with the nix flake's environment
shell:
    nix develop

# Open a PostgreSQL client to the local nbxplorer database
psql:
    psql -h localhost -U nbxplorer -d nbxplorer